xserver

xserver with xephyr scale patch
git clone https://git.neptards.moe/u3shit/xserver.git
Log | Files | Refs | README | LICENSE

meson.build (1195B)

      1 modesetting_srcs = [
      2     'dri2.c',
      3     'driver.c',
      4     'drmmode_display.c',
      5     'dumb_bo.c',
      6     'pageflip.c',
      7     'present.c',
      8     'vblank.c',
      9 ]
     10 
     11 shared_module(
     12     'modesetting_drv',
     13     modesetting_srcs,
     14     name_prefix: '',
     15 
     16     include_directories: [inc, xorg_inc],
     17     c_args: xorg_c_args,
     18     dependencies: [
     19         common_dep,
     20         udev_dep,
     21         libdrm_dep,
     22         gbm_dep,
     23     ],
     24 
     25     install: true,
     26     install_dir: join_paths(module_dir, 'drivers'),
     27 )
     28 
     29 # Test that we don't have any unresolved symbols from our module to Xorg.
     30 xorg_build_root = join_paths(meson.build_root(), 'hw', 'xfree86')
     31 symbol_test_args = []
     32 symbol_test_args += join_paths(xorg_build_root, 'libxorgserver.so')
     33 symbol_test_args += join_paths(xorg_build_root, 'dixmods', 'libshadow.so')
     34 if gbm_dep.found()
     35     symbol_test_args += join_paths(xorg_build_root, 'glamor_egl', 'libglamoregl.so')
     36 endif
     37 symbol_test_args += join_paths(xorg_build_root, 'drivers', 'modesetting', 'modesetting_drv.so')
     38 
     39 install_man(configure_file(
     40     input: 'modesetting.man',
     41     output: 'modesetting.4',
     42     configuration: manpage_config,
     43 ))
     44 
     45 test('modesetting symbol test',
     46     xorg_symbol_test,
     47     args: symbol_test_args,
     48 )